Category Archives: 谷口

Excelには便利な機能があって、漢字にフリガナを振ってくれる機能があります。

エクセル画面で右クリックをして……

「ふりがなの表示」を押すと……

こんな感じで自動で振ってくれます。

ところで、HTMLのタグで、<ruby>タグというものを知っていますか？

ルビ（ふりがな）を付ける

HTMLページで、対応しているブラウザではルビを表示してくれるタグです。

例えば「今日」という単語をルビ付きで表示したいときは、

<ruby>今日<rp>（</rp><rt>きょう</rt><rp>）</rp></ruby>

みたいに長ったらしく記述しなければなりません。

今回は、このExcelのルビをHTMLタグの記述に変換しようという試みです。

ぶっちゃけ大変でした。

最初は関数だけでなんとかなると思ってたんですが、結局ムリで、VBAでマクロ組むしかなかったです。

それでは、マクロのコードがこんな感じです。

Sub OutputScripts()

    '出力準備
    Dim pass As String
    pass = Left(ActiveWorkbook.FullName, Len(ActiveWorkbook.FullName) - Len(ActiveWorkbook.Name))
    pass = pass + "\output.txt"
    Open pass For Output As #1

    'セルを1文字ずつ検証
    Dim x As Integer
    Dim y As Integer
    For y = 2 To 3

        '出力用
        Dim output_text As String
        output_text = ""

        For x = 2 To 4
            'セルのテキスト
            Dim cel_text As String
            cel_text = Cells(y, x)

            'ふりがなの数
            Dim furigana_count As Integer
            furigana_count = Cells(y, x).Phonetics.Count

            'もし0個なら
            If furigana_count = 0 Then
                'そのまま格納
                output_text = output_text & """" & cel_text & ""","
            Else
                '検証文字の位置
                Dim pos As Integer
                pos = 1

                '変換後の文字列
                Dim update_text As String
                update_text = ""

                'for文をまわす
                For daf = 1 To furigana_count
                    'ふりがなと位置と文字数取得
                    Dim start_num As Integer
                    Dim end_num As Integer
                    start_num = Cells(y, x).Phonetics(daf).start
                    end_num = Cells(y, x).Phonetics(daf).Length

                    '漢字以外の文字をきりとる
                    Dim other As Integer
                    other = start_num - pos
                    update_text = update_text & Mid(cel_text, pos, other)

                    'もとの漢字
                    Dim kanzi As String
                    kanzi = Mid(cel_text, start_num, end_num)
                    'ふりがな
                    Dim furigana As String
                    furigana = Cells(y, x).Phonetics(daf).Text

                    update_text = update_text & "<ruby>" & kanzi & "<rp>（</rp><rt>" & furigana & "</rt><rp>）</rp></ruby>"

                    '位置記録
                    pos = start_num + end_num
                Next daf

                '残りの文字
                Dim nokori_num As Integer
                nokori_num = Len(cel_text) - pos + 1
                update_text = update_text & Mid(cel_text, pos, nokori_num)

                '変換して格納
                output_text = output_text & """" & update_text & ""","
            End If
        Next x

        '出力
        Print #1, output_text

    Next y

    'ファイルクローズ
    Close #1

End Sub

xとyという変数で2重のfor文を回すことで、セルを順番に検証しています。
Cells(y, x).Phonetics(daf).start　という記述で、フリガナが振られた漢字の位置が特定でき、
Cells(y, x).Phonetics(daf).Length　という記述で、フリガナが振られた漢字数が特定できます。

あとは、文字列の切り取りや連結を駆使して、最終的に変換したい形へ近づけていくだけです。

このマクロを再生すると、こういうテキストファイルが生成されます。

"こんにちは！　<ruby>今日<rp>（</rp><rt>キョウ</rt><rp>）</rp></ruby>はいい<ruby>天気<rp>（</rp><rt>テンキ</rt><rp>）</rp></ruby>ですね！","<ruby>日差<rp>（</rp><rt>ヒザ</rt><rp>）</rp></ruby>しが<ruby>温<rp>（</rp><rt>アタタ</rt><rp>）</rp></ruby>かくて、とても<ruby>気持<rp>（</rp><rt>キモ</rt><rp>）</rp></ruby>ちいい！","こんな<ruby>日<rp>（</rp><rt>ヒ</rt><rp>）</rp></ruby>はお<ruby>散歩<rp>（</rp><rt>サンポ</rt><rp>）</rp></ruby>でもして、のんびり<ruby>過<rp>（</rp><rt>ス</rt><rp>）</rp></ruby>ごしたいですね。",
"うめぼしたべたい","うめぼしたべたい<ruby>僕<rp>（</rp><rt>ボク</rt><rp>）</rp></ruby>は","<ruby>今<rp>（</rp><rt>イマ</rt><rp>）</rp></ruby>すぐ<ruby>君<rp>（</rp><rt>キミ</rt><rp>）</rp></ruby>に<ruby>逢<rp>（</rp><rt>ア</rt><rp>）</rp></ruby>いたい",

これで、だいぶ互換性の高い文字列になるんじゃないでしょうか。